原版加工厂提供了添加物品、方块、食物、流体、创造标签等原版东西的方法。  需要用import mods.contenttweaker.VanillaFactory;导入原版加工厂包。  当你添加了物品、方块等其他内容后，你需要提供语言文件、材质、BlockState、Model（如果你需要建模的话）。保存在游戏根目录\resources\contenttweaker目录下，这块内容类似于材质包制作，我不讲解。  CoT疑似集成了[Resource Loader](<a href="https://www.curseforge.com/minecraft/mc-mods/resource-loader" target="_blank">https://www.curseforge.com/minecraft/mc-mods/resource-loader</a>)这个mod，本来是这个mod才提供了resources文件夹，不过我还是推荐再添加这个mod。RL有个屑特性，resources文件夹内的语言文件会被自动改编码，导致本地化时zh_cn.lang不可用，会乱码。943汉化天空树厂4就遇到这个问题，你可以用u码转义防止编码改掉的影响，或者直接尝试用zs本地化。（见基本运用--物品名称修改 章）用zs本地化的脚本加载器是CraftTweaker，记得分脚本！

需要import mods.contenttweaker.Item;导入有关包。原版加工厂包也需要导入！

用val testItem as Item = VanillaFactory.createItem(字符串物品ID);呼出一个物品类的一个实例，并存储在某个变量中，以做接下来的修改。物品ID必须全小写，可以包含数字和下划线_ ，必须字母开头。

然后你对这个对象用一堆ZenProperties(既是ZenSetter，也是ZenGetter)设置这个物品的一些定义信息。最后用register方法将这个物品注册进游戏，注意注册后你不能对该物品再次修改，这样一个自定义物品就做好了。材质放在\resources\contenttweaker\textures\items文件夹，文件名与物品ID一致。

本地化key为item.contenttweaker.物品ID.name

以下为基础的ZenProperties（剩余的基本无用或需要函数参数，为高级运用，将在之后讲解）

示例脚本

#loader contenttweaker

import mods.contenttweaker.VanillaFactory;

import mods.contenttweaker.Item;



val zsItem as Item = VanillaFactory.createItem("zs_item");

zsItem.maxDamage = 8848;

zsItem.rarity = "rare";

zsItem.creativeTab = <creativetab:tools>;

zsItem.toolClass = "pickaxe";

zsItem.toolLevel = 5;

zsItem.beaconPayment = true;

zsItem.register();

需要import mods.contenttweaker.Block;导入有关包。原版加工厂包也需要导入！

用val testBlock as Block = VanillaFactory.createItem(字符串方块ID, BlockMaterial);呼出一个方块类的一个实例，并存储在某个变量中，以做接下来的修改。ID必须全小写，可以包含数字和下划线_ ，必须字母开头。
设定的BlockMaterial将会影响方块的一些特性。

接下来操作与物品类似。材质放在\resources\contenttweaker\textures\blocks文件夹，文件名与物品ID一致。

本地化key为tile.contenttweaker.方块ID.name

可用的ZenProperties(其它基本无用，或为事件高级运用)

示例脚本

#loader contenttweaker



import mods.contenttweaker.VanillaFactory;

import mods.contenttweaker.Block;



var antiIceBlock as Block = VanillaFactory.createBlock("anti_ice", <blockmaterial:ice>);

antiIceBlock.lightOpacity = 3;

antiIceBlock.LightValue = 0;

antiIceBlock.blockHardness = 1.0;

antiIceBlock.blockResistance = 5.0;

antiIceBlock.toolClass = "pickaxe";

antiIceBlock.toolLevel = 0;

antiIceBlock.blockSoundType = <soundtype:snow>;

antiIceBlock.slipperiness = 0.75;

antiIceBlock.register();

需要import mods.contenttweaker.Fluid;导入有关包。原版加工厂包也需要导入！

用val testFluid as Fluid = VanillaFactory.createItem(字符串流体ID, int表示RGB模式颜色);呼出一个流体类的一个实例，并存储在某个变量中，以做接下来的修改。ID必须全小写，可以包含数字和下划线_ ，必须字母开头。

流体的材质会根据所给的用颜色参数进行染色，让你方便制作出各种颜色的“水”或“熔岩”，而不用设定材质。

本地化的key为fluid.流体ID

可用的ZenProperties

示例脚本

#loader contenttweaker

import mods.contenttweaker.VanillaFactory;

import mods.contenttweaker.Fluid;



var zsFluid as Fluid = VanillaFactory.createFluid("zs_fluid", 0xFF69B4);

zsFluid.temperature = 500;

zsFluid.viscosity = 1500;

zsFluid.density = 1500;

zsFluid.luminosity = 4;

zsFluid.stillLocation = "base:fluids/liquid";

zsFluid.flowingLocation = "base:fluids/liquid_flow";

zsFluid.register();

真正要有mod的样，应该有属于自己的创造标签。

需要import mods.contenttweaker.CreativeTab;导入相关包，原版加工厂包也需要导入！

用val testTab as CreativeTab = VanillaFactory.createItem(字符串创造标签ID, 一个东西表示图标);

图标可以用以下三个类中其中之一（还有个IItemStackSupplier是函数高级运用，跳过）

• 
  

  IItemStack：物品堆。注意CoT表示IItemStack的尖括号调用，开头必须为item:，不可省略。

  
  


• 
  

  Item：CoT注册物品

  
  


• 
  

  Block：CoT注册方块

  
  

本地化key为itemGroup.创造标签ID

之后你就可以用\<creativetab:你填的ID\>，来给添加的物品方块指定创造标签了。

实例脚本

#loader contenttweaker

import mods.contenttweaker.CreativeTab;

import mods.contenttweaker.VanillaFactory;

import mods.contenttweaker.Item;



val zsTab as CreativeTab = VanillaFactory.createCreativeTab("contenttweaker", <item:minecraft:dragon_egg>);

zsTab.register();



val zsItem as Item = VanillaFactory.createItem("test_item");

zsItem.creativeTab = <creativetab:contenttweaker>;

zsItem.register();