[BGM]实用的配方自定义mod-Minetweaker3教程！[11/22更新] - Mod研讨

SSCXM

本帖最后由 zjxx 于 2018-3-24 12:25 编辑

前言
想自定义配方？想修改某些机器的配置？想自定义矿物词典？那么，minetweaker（下面简称mt）这个mod可以满足您的需求。
通过一些简单的脚本语句就能实现强大的自定义配方功能！
下载地址在：http://minetweaker3.powerofbytes.com/ 或者看我的搬运贴：http://www.mcbbs.net/thread-306970-1-1.html
下面我对这个mod的使用方法进行一个具体的介绍（可能有错误，欢迎指正！）

↓音乐↓

壹、安装
将此mod拖入mods文件夹即可使用，需要forge API

贰、起步

一、脚本
编写脚本是minetweaker里的基本操作
mods文件夹加入mt之后，你应该能在.minecraft里面找到一个名为scripts dictionary的文件夹，所有的脚本文件都会存放在这里，mt脚本文件的末尾均为.zs
我们来试试编写我们的第一个脚本吧wwwww（以下符号均为英文标点）
1、print语句

print("要显示的文本");

复制代码

这个语句的功能是在你进图后在聊天框内显示引号内的文字
譬如（经典老梗）：

print("hello world")

复制代码

将这段代码黏贴到记事本或notepad++（推荐）内，将文件保存为.zs后缀的文件，譬如hello.zs
之后放入.minecraft/scripts dictionary文件夹下，启动游戏，该文件夹下可以放置任意多的脚本文件，他们都会被加载但是我们的语句被打印到哪里了呢？

二、mt日志
print语句打印的文字会被记录在这个名为minetweaker.log的日志文件里，在上一个例子中，你应该能在日志文件中找到这句话……

INFO: Hello world!

复制代码

当然这个功能实在是太普通了……不过日志文件有助于检测你的编写错误等等……
如果你的游戏还开着的话试试在游戏里输入这个指令

/minetweaker names

复制代码

wow，所有游戏里面物品和方块的名字都被导出到了minetweaker.log里，这个语句今后有大用……

三、脚本重新装载指令
编写配方的时候经常面临调整……重新开游戏调整好烦的，不是么？
这个指令能节省大量的启动时间……

/minetweaker reload

复制代码

哦，“hello world”貌似又出现了一遍wwwww，log内也会出现

四、注释
注释语句能够在密密麻麻的代码中增加一些提示性却又不影响代码功能的文字，如果你想标注每行代码是做什么用的尽管来吧
注释有以下三种格式
1、注释格式1（单行）

// 注释文字

复制代码

2、注释格式2（单行）

# 注释文字

复制代码

3、注释格式3（多行）

/* 多行
注释
文字 */

复制代码

叁、基本配方编辑

注：以下教程仅针对1.7.2版本，1.6.4稍有不同
一、合成配方语句
1、有序合成配方添加语句

recipes.addShaped(配方输出, 配方标记);

复制代码

这个语句能够添加一某个物品（配方输出）的一个有序合成配方
当然别急着用它……我们先熟悉下配方标记……配方标记是mt中对于一个九宫格配方的描述
比如铁护腿，我们在游戏内的配方应该是这样的……

在mt语句中，他对应的配方标记是这样的……

[[<minecraft:iron_ingot>, <minecraft:iron_ingot>, <minecraft:iron_ingot>],
[<minecraft:iron_ingot>, null, <minecraft:iron_ingot>],
[<minecraft:iron_ingot>, null, <minecraft:iron_ingot>]]

复制代码

也许它有点抽象……下面我们看看一个具象的描述（当然真正写的时候可不能这样！）

每一个物品和方块都有mt内唯一对应的名字，在语句编写中用尖角括号“<>”包裹，被称为物品标记,（今后凡是带尖角括号的文字均被称为“标记”）比如上面的<minecraft:iron_ingot>表示铁锭，<minecraft:iron_leggings>表示的就是铁护腿啦，空的地方用null表示，使用前面提到的names指令可以得到所有物品的名称，1.7.2中，物品标记的名称通常是：

<mod名称:物品名>

复制代码

*1.6.4版本中，你也可以使用ID作为配方标记，格式就是<ID:meta>
**1.6.4版本中，物品标记通常张这样：<item.hatchetStone>
好了，我们来看看一个简单的例子（修改木棍合成）：

recipes.addShaped(<minecraft:stick> * 4, [[<minecraft:planks>, null], [null, <minecraft:planks>]]);

复制代码

如图所示的配方

但是这个语句有个问题，它只能使用特定的木棍！

我们使用通配符（*）来解决这个问题

recipes.addShaped(<minecraft:stick> * 4, [[<minecraft:planks:*>, null], [null, <minecraft:planks:*>]]);

复制代码

大快人心有木有www

2、无序合成配方添加语句

recipes.addShapeless(配方输出, 配方标记);

复制代码

作用是添加一个无序合成配方
3、配方移除语句

recipes.remove(需要删除配方的物品标记);

复制代码

即删除该物品所有的配方
4、特定配方移除语句

recipes.removeShaped(需要删除配方的物品标记,需要删除的特定配方标记);

复制代码

专一地删除某一特定配方而不影响其余的
如果某个物品有有序或无序配方的话你也可以专一删除有序配方或无序配方

recipes.removeShaped(需要删除配方的物品名标记); //用于删除有序配方
recipes.removeShapeless(需要删除配方的物品名); //用于删除无序配方

复制代码

二、其他
1、变量赋值语句
老是写长长的物品标记太烦？试试用变量吧！

val 变量名 = 物品标记;

复制代码

之后的语句编写中可以直接使用变量名进行编写，变量相当于一个带“<>”的标记，譬如：

val stick = <minecraft:stick>;
val planks = <minecraft:planks:*>;
recipes.remove(stick);
recipes.addShaped(stick * 4, [[planks, null], [null, planks]]);

复制代码

另一个变量赋值语句是var语句，格式：

var 变量名 = <物品名>;

复制代码

两者的区别是val语句只认第一次的赋值而无视之后的赋值，比如

val stick = <minecraft:stick>;
val stick = <minecraft:bread>；

复制代码

最终stick变量仍然对应木棍而非面包
2、带meta物品的标记
子物品语句针对同ID而不同meta的物品使用，比如煤和木炭，两者的名字都是minccraft:coal……
编写语句时为了区分他们你应该这样……

var coal = <minecraft:coal:0>; // 相当于 <minecraft:coal>
var charcoal = <minecraft:coal:1>;</font>

复制代码

这样，coal即对应煤，而charcoal即对应木炭
如果你需要用一个变量同时表示煤和木炭的时候你可以用上通配符……

var anyCoal = <minecraft:coal:*>;

复制代码

这样，anyCoal这个变量就同时表示煤和木炭了
3、带损耗物品的标记
mt默认的物品是没有损耗的，当您需要将带有损耗的物品用于合成的时候……

var pick = <minecraft:stone_pickaxe>;
var iron = <minecraft:iron_ingot>;
// 机智的稿子升级配方XD
recipes.addShaped(<minecraft:iron_pickaxe>, [[iron, iron, iron], [null, pick, null]]);

复制代码

这个情况下用于合成的石镐子必须无损……实在not fashion，我们需要.anyDamage()这个小尾巴的帮助！

var pick = <minecraft:stone_pickaxe>.anyDamage();
var iron = <minecraft:iron_ingot>;
// 机智的稿子升级配方XD
recipes.addShaped(<minecraft:iron_pickaxe>, [[iron, iron, iron], [null, pick, null]]);

复制代码

这下就能使用任何损耗值的石镐子了w

肆、矿典编辑

要理解这节的内容……首先安装一个IC2（工业2）吧！
*以下内容引用自mc百科站站长重生的百度贴吧帖子~

forge矿物辞典（forge ore dictionary，下面简称OD）来源于RedPower2的作者eloraam的一个帖子，当时有人争议rp(红石mod)和ic(工业mod)添加同类的矿物(铜矿、锡矿)引起的混乱，于是forge矿物辞典随之诞生了。forge矿物辞典就是一种让不同模组的矿物通用的系统，例如在世界中采集到不同的铜矿，可以用来合成同样的物品，甚至可以混搭使用！

大部分mod，如IC2，TE，TiC，RC，FR等均采用了矿物辞典登记自己的矿物，如IC2的铜锭登记IngotCopper，TE铜矿OreCopper
矿物辞典在多mod通用方面起着重要作用
一、在脚本中引用OD
多mod情况下，比如IC+TE，当你想用青铜等两mod兼有的矿物编写配方的时候……物品名称只能对应一个物品，而平时两个mod的青铜是通用的……
那么仅用物品名就有个蛋疼的问题，必须把所有情况都写一遍！
比如配方里要用1块青铜……就得写两个配方
2块得写4种情况……
3块……你们自己算吧！
此时我们引用矿物辞典就可以省去许多麻烦
我们结合一些实例讲解吧（直接合成高级合金）
你也许会这么写……

val copper = <IC2:itemIngotCopper>;
val tin = <IC2:itemIngotTin>;
val iron = <minecraft:iron_ingot>;
recipes.addShaped(<IC2:itemPartAlloy>, [[iron, iron, iron], [copper, copper, copper], [tin, tin, tin]]);

复制代码

事实上你会得到……

但如果有其他有铜有锡的mod怎么办呢？

配方失效了！这时候我们应该……

val copper = <ore:ingotCopper>;
val tin = <ore:ingotTin>;
val iron = <ore:ingotIron>;
recipes.addShaped(<IC2:itemPartAlloy>, [[iron, iron, iron], [copper, copper, copper], [tin, tin, tin]]);

复制代码

这个配方用于合成IC的混合金属锭，把青铜替换成了铜

这样只要其余mod的铜在OD中登记为IngotCopper，即可用于此配方
矿典标记通常是这样……

<ore:矿典名>;

复制代码

利用NEI可以轻易地查询到矿典名，当然，熟悉其构造方式的你也可以直接写……
二、自定义OD条目
作为一个不（ai）屈（zuo）服（si）于（chao）命（ji）运（xiong）的人，我们当然希望用自己的左右手自定义OD条目！
1、OD添加语句

矿典标记.add(物品标记);

复制代码

将某个物品添加到某个OD条目中，比如这个例子

val copper = <ore:ingotCopper>;
val tin = <ore:ingotTin>;
val iron = <ore:ingotIron>;
iron.add(<minecraft:coal>);
recipes.addShaped(<IC2:itemPartAlloy>, [[iron, iron, iron], [copper, copper, copper], [tin, tin, tin]]);

复制代码

这样，在这个配方里，煤=铁，同样在其他情况下，只要使用的是铁的OD，煤都能跟铁等价互换！

2、OD移除语句
看某个物品的OD不爽？试试这个！

矿典标记.remove(物品标记);

复制代码

将某个属于该OD条目下的物品从该OD条目中移除
3、OD映射语句

矿典标记A.mirror(矿典标记B);

复制代码

将所有属于A条目的物品映射到B条目，比如

<ore:ingotIron>.mirror(<ore:ingotTin>);

复制代码

这个情况下，铁被映射到锡，这样所有锡都可以被铁替换，而锡不能替换铁

4、OD融合语句

矿典标记A.addAll(矿典标记B);

复制代码

和映射标记相似，这个情况下A对应的所有物品会被列入B条目下
使用映射语句和融合语句可以实现矿典统一化，方法：先融合，再统一
5、新增OD
输入一个从未存在的OD条目名会被mt认为是新增了一个OD条目，你可以用它编辑许多配方！
如：

val myEntry = <ore:myOwnEntry>;
myEntry.add(<minecraft:coal>);
myEntry.add(<minecraft:iron_ingot>);

复制代码

相当于新增了一个名为“myEntry”的OD条目，铁和煤包含其中

伍、熔炉和燃料编辑

陆、高级配方编辑

一、自定义NBT标签
TF研究所传来了兴奋的呼声！MT能够自定义NBT！
不知道NBT是啥？快看看SYL桑的NBT教程！特别鸣谢HAYO研究所的@sylqiuyifeng
适当NBT能使游戏变得生♂动♀活♂泼，待我们慢慢道来……
1、带NBT标签的物品标记
当我们想对物品的耐久，名字，甚至是名称动手脚的时候……

val stick = <minecraft:stick>;
val pick = <minecraft:stone_pickaxe>;
val damagedPick =pick.withDamage(10);
val stickedPick = pick.withTag({display: {Name: "Sticked pick", Lore: ["This pick", "Has been sticked"]}});
recipes.addShaped(damagedPick, pick, stick);
recipes.addShaped(stickedPick, [[pick, stick], [stick, stick]]);

复制代码

执行这个脚本后，用一个木棒加上一个木棍可以获得一个耐久度仅剩10的石镐子，即“damagedPick”
而用三个木棍加上一个石镐子能得到一个被命名为“Sticked pick”的稿子，如图：

修改NBT标签的乐趣还有很多，SYL桑的介绍已经相当翔实，这里我个伪触就不再赘述了，相信有勇气点开这个分页的你一定能够理解！
标记格式总结:

物品标记.withDamage(损耗值); //对应特定损耗值的物品
物品标记.withTag({display: {Name: "文本", Lore: ["文本"]}}); //为某物品添加特定的NBT标签

复制代码

2、限定NBT标签的配方编写
你可以限定一个带NBT标签的物品用于合成！

val stick = <minecraft:stick>;
val pick = <minecraft:stone_pickaxe>;
val damagedPick = pick.withDamage(10);
val stickedPick = pick.withTag({display: {Name: "Sticked pick", Lore: ["This pick", "Has been sticked"]}});
recipes.addShaped(damagedPick, pick, stick);
recipes.addShaped(stickedPick, [[pick, stick], [stick, stick]]);
val stonedPick = pick.withTag({display: {Name: "Stoned pick", Lore: ["This pick", "Has been experimenting too much"]}});
val onlyStickedPick = pick.onlyWithTag({display: {Name: "Sticked pick"}});
val cobble = <minecraft:cobblestone>;
recipes.addShaped(stonedPick, [[onlyStickedPick, cobble], [cobble, cobble]]);

复制代码

在“onlyStickedPick”位置上仅能实用NBT名字标签为“Sticked pick”的稿子，描述部分被忽略
其他的NBT限定条件语句

物品标记.onlyDamaged(); // 仅对应已损耗的物品
物品标记.onlyDamageAtLeast(损耗值A); // 仅对应损耗值不少于A的物品
物品标记.onlyDamageAtMost(损耗值A); // 仅对应损耗值不多于A的物品
物品标记.onlyDamageBetween(损耗值A, 损耗值B); // 仅对应损耗值在A~B间（A<B）的物品

复制代码

同时增加多个限定条件也是可行的，如

pick.onlyDamage(10);.onlyWithTag({display: {Name: "Sticked pick", Lore: ["This pick", "Has been sticked"]}})

复制代码

二、合成原料的重复使用和转换
想在配方当中使用工具又不想吞配方？看看下面这个实例：（石斧增加木棍产量）
也许你会这么写（忘记忽略损耗了XD）：

recipes.addShapeless(<item.stick> * 3, [<item.hatchetStone>, <ore:woodPlanks>]);

复制代码

但是斧头被吞了！这不科学！试试下面这个例子……

recipes.addShapeless(<minecraft:stick> * 3, [<minecraft:stone_axe>.reuse(), <ore:plankWood>]);

复制代码

好的，这下斧头就不会再丢掉了……不过没有一丁点损耗貌似不平衡吧……

recipes.addShapeless(<minecraft:stick> * 3, [<minecraft:stone_axe>.transformDamage(), <ore:plankWood>]);

复制代码

这次，每合成三个木棍会消耗石斧头的一点耐久并上一块木板，想消耗更多的耐久么？

recipes.addShapeless(<minecraft:stick> * 3, [<minecraft:stone_axe>.transformDamage(4), <ore:plankWood>]);

复制代码

这次，每次合成要消耗4点耐久（话说你们看的出来么……）
.transform不仅仅能够变换耐久，还能够变换物品！，看看这个实例（土+小麦+水桶=草）

recipes.addShaped(<minecraft:grass>, [[
<minecraft:dirt>,
<minecraft:water_bucket>.transformReplace(<minecraft:bucket>),
<minecraft:wheat>
]]);

复制代码

合成后，水桶会变成空桶

柒、物品重命名

捌、mod支持

mod支持方面内容甚多，我建议您准备好英汉词典……因为我不可能讲的非常细！
一、对于NEI的支持
不想在NEI看见某个物品？想在NEI列表内添加独一无二的物品？想更改物品在NEI内显示的名字？看看下面这个实例

import mods.nei.NEI;

复制代码

要启用对NEI的支持，首先需要一行……

import mods.nei.NEI;

复制代码

要隐藏某个物品，只要……

NEI.hide(物品标记);

复制代码

在NEI内添加特定NBT标签的物品：

NEI.addEntry(物品标记.withTag({display: {Name: "显示名称", Lore: ["注释语句"]}}));

复制代码

修改某个物品在NEI内的显示名称：

NEI.overrideName(物品标记, "名称");

复制代码

二、对于IC2的支持

好了我们可以跟那些机器搞基了
-Sin Cavindish

来对IC2的机器下手吧！
1、将电动工具用于合成
类似我们在第陆部分看到的……这里给上实例给大家理解就好了（电锯增产木板）

val chainsaw = <IC2:itemToolChainsaw>.anyDamage();
recipes.addShapeless(<minecraft:stick> * 3, [<ore:plankWood>, chainsaw.onlyIC2ChargeAtLeast(100).transformIC2Discharge(100)]);

复制代码

电力大于等于100的电锯才能用于合成，每次合成消耗100点电力

2、机（gao）器（ji）
目前支持修改的机器有：

灌装机
压缩机
提取机
打粉机
金属成型机
洗矿场
回收机
热力离心机

大一览表：

import mods.ic2.Canner;
import mods.ic2.Compressor;
import mods.ic2.Extractor;
import mods.ic2.Macerator;
import mods.ic2.MetalFormer;
import mods.ic2.OreWasher;
import mods.ic2.ThermalCentrifuge;
// TODO: make some proper examples and test them
Canner.addBottleRecipe(output, container, fillIngredient);
Canner.addBottleRecipe(output, container, water);
Canner.addEnrichRecipe(output, input, additiveItem);
Canner.addEnrichRecipe(output, input, additiveLiquid);
Compressor.addRecipe(<minecraft:planks>, <minecraft:stick>);
Extractor.addRecipe(<minecraft:wheat>, <minecraft:bread>);
Macerator.addRecipe(<minecraft:wheat> * 2, <minecraft:bread>);
MetalFormer.addCuttingRecipe(<minecraft:stick> * 3, <minecraft:planks:*>);
MetalFormer.addExtrudingRecipe(<minecraft:stick> * 3, <minecraft:planks:*>);
MetalFormer.addRollingRecipe(<minecraft:stick> * 3, <minecraft:planks:*>);
OreWasher.addRecipe([<minecraft:wheat>, <minecraft:wheat_seeds>], <minecraft:bread>, 1000); // 1000 = water usage
ThermalCentrifuge.addRecipe([<minecraft:wheat>, <minecraft:wheat_seeds>], <minecraft:bread>, 1000); // 1000 = minimum temperature

复制代码

太多了……而且都差不多的样子，结合英汉词典自己琢磨吧！
3、回收机黑名单
讨厌廉价的东西用于回收机？

import mods.ic2.Recycler;
Recycler.addBlacklist(物品标记);

复制代码

禁止某一（类）物品用于回收机生产废料
4、为半流体发电机添加燃料

import mods.ic2.SemiFluidGenerator;
SemiFluidGenerator.addFluid(<liquid:lava> * 10, 5);

复制代码

前面的小分句对应每一发电周期消耗的液体的种类和数量（单位mB，一桶水=10^3mB），后面是每tick的发电量（1s=20ticks）
5、自定义废料箱物品及概率

import mods.ic2.ScrapBox;
ScrapBox.addDrop(<minecraft:emerald>.weight(0.05));

复制代码

前一小分句对应可能出现的物品，后面半句对应概率，生成钻石的概率值为0.1，泥土为5，木工具为1

三、对于GT的支持

大格雷科技将统一世界！-沙皇@MarcoV 二世

阅读以下内容请拿好有道词典！

import mods.gregtech.AlloySmelter;
import mods.gregtech.Assembler;
import mods.gregtech.BlastFurnace;
import mods.gregtech.Canner;
import mods.gregtech.Centrifuge;
import mods.gregtech.CNC;
import mods.gregtech.ChemicalReactor;
import mods.gregtech.DistillationTower;
import mods.gregtech.Electrolyzer;
import mods.gregtech.ForgeHammer;
import mods.gregtech.Fuels;
import mods.gregtech.FusionReactor;
import mods.gregtech.Grinder;
import mods.gregtech.ImplosionCompressor;
import mods.gregtech.Lathe;
import mods.gregtech.PlateBender;
import mods.gregtech.PlateCutter;
import mods.gregtech.Sawmill;
import mods.gregtech.Sonictron;
import mods.gregtech.VacuumFreezer;
import mods.gregtech.Wiremill;
// 以下仅1.6.4
import mods.gregtech.ComputerCube;
import mods.gregtech.JackHammer;
// 以下仅1.7.2
import mods.gregtech.Aplifabricator;
import mods.gregtech.Boxing;
# TODO: replace with real examples
# Soon there will be the complete API documentation
AlloySmelter.addRecipe(output, input1, input2, durationTicks, euPerTick);
Assembler.addRecipe(output, input1, input2, durationTicks, euPerTick);
BlastFurnace.addRecipe(output, input1, input2, durationTicks, euPerTick, temperature);
BlastFurnace.addRecipe([output1, output2], input1, input2, durationTicks, euPerTick, temperature);
Canner.addRecipe(output, input1, input2, durationTicks, euPerTick);
Canner.addRecipe([output1, output2], input1, input2, durationTicks, euPerTick);
Centrifuge.addRecipe([output1, output2, output3, output4], input, cells, durationTicks);
Centrifuge.addRecipeFuelCan([output1, output2, output3, output4], input, durationTicks);
ChemicalReactor.addRecipe(output, input1, input2, durationTicks);
DistillationTower.addRecipe(output, input, numCells, durationTicks, euPerTick);
DistillationTower.addRecipe([output1, output2, output3, output4], input, numCells, durationTicks, euPerTick);
Electrolyzer.addRecipe([output1, output2, output3, output4], input, cells, duration, euPerTick);
Extruder.addRecipe(output, input2 shape, durationTicks, euPerTick);
ForgeHammer.addRecipe(output, input, durationTicks, euPerTick);
Fuels.addDieselFuel(output, input, euPerMillibucket);
Fuels.addGasTurbineFuel(output, input, euPerMillibucket);
Fuels.addThermalGeneratorFuel(output, input, euPerMillibucket);
Fuels.addDenseFluidFuel(output, input, euPerMillibucket);
Fuels.addPlasmaGeneratorFuel(output, input, euPerMillibucket);
Fuels.addMagicGeneratorFuel(output, input, euPerMillibucket);
FusionReactor.addRecipe(output, input1, input2, durationTicks, energyPerTick, startEnergy);
Grinder.addRecipe(output, input);
Grinder.addRecipe(output, input1, input2);
Grinder.addRecipe([output1, output2, output3, output4], input);
Grinder.addRecipe([output1, output2, output3, output4], input1, input2);
ImplosionCompressor.addRecipe(output, input, numTnt);
ImplosionCompressor.addRecipe([output1, output2], input, numTnt);
Lathe.addRecipe(output, input, durationTicks, euPerTick);
Lathe.addRecipe([output1, output2], input, durationTicks, euPerTick);
PlateBender.addRecipe(output, input, durationTicks, euPerTick);
PlateCutter.addRecipe(output, input, durationTicks, euPerTick);
Sawmill.addRecipe(output, input1);
Sawmill.addRecipe(output, input1, input2);
Sawmill.addRecipe([output1, output2], input1);
Sawmill.addRecipe([output1, output2], input1, input2);
Sonictron.addSound(item, soundName);
VacuumFreezer.addRecipe(output, input, durationTicks);
Wiremill.addRecipe(<item.stick> * 3, <tile.wood>, 20, 1);
// 以下仅1.6.4
ComputerCube.addDescriptionSet([item1, item2, ...], [textLine1, textLine2, ...]);
JackHammer.addMinableBlock(item);
JackHammer.addDiamondMinableBlock(item);
// 以下仅1.7.2
Amplifabricator.addAmplifier(item, durationTicks, amount);
Boxing.addBoxingRecipe(fullBox, item, emptyBox, durationTicks, euPerTick);
Boxing.addUnboxingRecipe(item, emptyBox, fullBox, durationTicks, euPerTick);

复制代码

四、对于更多mod的支持

不想统一世界的熊孩子不是好小学生 -Cot Meon

只支持那么几个mod不爽？
minetweaker有个基友mod叫做modtweaker！它极大地扩展了mt的自定义空间！
想知道它支持什么么？

Blood Magic（血魔法）
Botania（植物魔法）
Ex Nihilo（空岛辅助？）
Factorization（因式分解和工厂化）
Hardcore Ender Expansion（更难的末地扩展）
Mariculture（毛依物语/海洋）
Mekanism （通用机械）
Metallurgy 4（冶金4）
PneumaticCraft（气动工艺）
Railcraft（铁路）
Thaumcraft 4（神秘时代4）
Tinker's Construct（匠魂）

以及一些原版的增强！
modtweaker的1.6.4版本仅支持minetweaker2，更多详情请见其官方wiki！（备好牛津英汉辞典！）

⑨、shxq君跟新的零散教程

高三之后没什么时间再来钻研了……不过幸亏有shxq君在坚持不懈的学习MT因此后面的更新交给他了……感谢@shxq 君
循环语句教程在82楼
祝大家使用愉快！我是sin，望大家天天进步！

更新日志：

14/11/22
增加第⑨部分
14/08/12
增加音乐
14/08/06
增加图片，更正了部分错误，感谢mt狂人@exzhawk !
14/07/30
完成捌，完结撒花！
14/07/29
更新陆，修正部分肆的内容
14/07/21
开始翻译，完成壹，贰，叁
14/07/23/
开始编辑肆，新增捌
14/07/24/
完成肆，伍，柒

1277832129

表示插件写配方轻松多了不过不能单机用

魔君

好顶赞OAO(话说又一个新版主)

SSCXM

1277832129 发表于 2014-7-21 14:30
表示插件写配方轻松多了不过不能单机用

这个功能比较强大就是了，能给工业啦格雷啦这些的机器添加配方，官方也表示正在兼容神秘4，就是说我们可以自定义注魔祭坛什么的www

sb023612

去发搬运帖吧……

tsubasa56

酷爱更新删打粉机配方的代码

SSCXM

sb023612 发表于 2014-7-21 14:44
去发搬运帖吧……

modtweaker仅支持MT2

SSCXM

自顶

SSCXM

顶！

1043357338

SSCXM 发表于 2014-7-24 21:26
顶！

顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶顶！！！！！！！！

SSCXM

自顶！

MarcoV

卧槽这么多版主我都吓得不敢说话了

sb023612

原来还设了金锭奖励，不科学

SSCXM

自顶起

jjxxz2

大写字看着有点别扭

jjxxz2

居然有金锭？突然注意到

SSCXM

自顶……

时透无一年

顶一个拿金锭

huanghongxun

整合平衡什么的。。。。

chthonic

可以用这个自己添加了么..比如我想加入更多弓箭的类型，铁弓，金，钻弓什么的，先写配方然后再写耐久那个，然后呢？

SSCXM

增加了图片

SSCXM

……改个标题……

SSCXM

chthonic 发表于 2014-8-4 17:05
可以用这个自己添加了么..比如我想加入更多弓箭的类型，铁弓，金，钻弓什么的，先写配方然后再写耐久那个， ...

你可以吧煤变成武器，但是添加工具的话还是交给mod制作器吧

2424233599

已收藏~~~~~~~~~~~~~~~

SSCXM

增加音乐

无敌小阿沫

性哭了做得很不错啊！

washington

顶顶顶顶顶

morikawa

Mt教程必须顶起

lillili

额牛逼

时透无一年

帮忙顶一个

sb023612

我也来试试运气

琳琅素白

好东西要刷上去=w=

shxq

一下干掉Custom Recipes （自定义合成）和ZZZZZ Custom Configs（ZZZZZ自定义配置）两个mod

SSCXM

shxq 发表于 2014-8-12 17:04
一下干掉Custom Recipes （自定义合成）和ZZZZZ Custom Configs（ZZZZZ自定义配置）两个mod ...

你来啦ww

shxq

本帖最后由 shxq 于 2014-8-13 12:53 编辑

SSCXM 发表于 2014-8-13 12:38
你来啦ww

我在学习这个mod，重新编写合成公式，发现注解不能用中文。

煤炭转换

// Coal 2 Charcoal
recipes.addShapeless(<minecraft:coal>,[<minecraft:coal:1>]);
recipes.addShapeless(<minecraft:coal:1>,[<minecraft:coal>]);

复制代码

c2c.zip (220 Bytes, 下载次数: 19)
树苗转换

/*
OS = OakSapling
SS = SpruceSapling
BS = BirchSapling
JS = JungleSapling
AS = AcaciaSapling
DS = DarkOakSapling
NS = AnySapling (future using)
*/
val OS = <minecraft:sapling:0>;
val SS = <minecraft:sapling:1>;
val BS = <minecraft:sapling:2>;
val JS = <minecraft:sapling:3>;
val AS = <minecraft:sapling:4>;
val DS = <minecraft:sapling:5>;
val NS = <minecraft:sapling:*>;
//sapling Converter
recipes.addShaped(OS * 9,[[DS,DS,DS],[DS,DS,DS],[DS,DS,DS]]);
recipes.addShaped(SS * 9,[[OS,OS,OS],[OS,OS,OS],[OS,OS,OS]]);
recipes.addShaped(BS * 9,[[SS,SS,SS],[SS,SS,SS],[SS,SS,SS]]);
recipes.addShaped(JS * 9,[[BS,BS,BS],[BS,BS,BS],[BS,BS,BS]]);
recipes.addShaped(AS * 9,[[JS,JS,JS],[JS,JS,JS],[JS,JS,JS]]);
recipes.addShaped(DS * 9,[[AS,AS,AS],[AS,AS,AS],[AS,AS,AS]]);

复制代码

sapling.zip (415 Bytes, 下载次数: 25)

SSCXM

shxq 发表于 2014-8-13 12:50
我在学习这个mod，重新编写合成公式，发现注解不能用中文。

煤炭转换

原来如此

路邊電燈泡

嗯
我想我是來領金錠試試Try Try See的

lovelyandlucky

顶。。诶，干脆弄个末影珍珠围鸡蛋=龙蛋？

SSCXM

lovelyandlucky 发表于 2014-8-13 17:27
顶。。诶，干脆弄个末影珍珠围鸡蛋=龙蛋？

可以呀wwww

SSCXM

shxq 发表于 2014-8-13 12:50
我在学习这个mod，重新编写合成公式，发现注解不能用中文。

煤炭转换

加油，腐肉皮革，马具都做一遍好了

SSCXM

路邊電燈泡发表于 2014-8-13 16:51
嗯
我想我是來領金錠試試Try Try See的

果然现在的年轻人都已经懒到眼前的金锭都不拿了

路邊電燈泡

SSCXM 发表于 2014-8-16 13:21
果然现在的年轻人都已经懒到眼前的金锭都不拿了

現在只有回復可見才能激發懶...
金粒只能拿來買勳章和看末地

冥王星人

一个字没看懂

stool

我只是冲着金鼎来的← ←

飞鱼在天

看到没人要金锭就来了……

番茄茄

为何50%···

冥王星人

竟然没中，再来一次。。。

SSCXM

冥王星人发表于 2014-8-16 20:43
一个字没看懂

对于不玩mod的你来说辛苦了

大世界小师

牛B，这几天来冒个泡《明天做手术去喽》

13640419081

懂了嗯哼谢谢lz了

下一页最后一页